#!hs2

#####################################################################
# Script : OZPlan.hsm
# Description : Envoi et réception plannifiés du courrier et des news
#               La sélection Des FAIs se fait d'après une liste
#               préférientielle.
# Configuration : Les FAIs et les serveurs SMTP ET POP3 sont indiqués
#                 dans le fichier Fai.ini.
#                 Ne pas oublier de configurer aussi Hamster !
# Nécessite :
# - Fai.ini
# - Fai.hsm
# - News.hsm (BStrings.hsm, BMsgHeader.hsm, BFichierTexte.hsm)
# - Mail.hsm
# - Alerte.bat
#
# Auteur : Olivier Zolli <ozolli@online.fr>
# Version : 15/02/01
#####################################################################

#!load Fai.hsm
#!load News.hsm
#!load Mail.hsm

HamMessage(2,0)

# Lancement du planificateur
AtClear
AtAdd(Traitement,"08:00","19:00","1111100",60,True)
AtAdd(Traitement,"12:00","","0000011")
print( "Script OZPlan activé" )
AtExecute
quit

# Connexion, envoi, réception et déconnexion : Traitement
sub Traitement

print("SCRIPT EN COURS DE TRAITEMENT")

# Déclaration et initialisation des variables
VarSet($CxHamster,True)

# Traitement des articles entrants et sortants
# News Jobs
EnteteNews
HamNewsJobsClear
HamNewsJobsPostDef
HamNewsJobsPullDef
HamWaitIdle

# Teste si un FAI est déja connecté
if(RasIsConnected)
  $CxHamster=False
  print("Déja connecté à "+RasGetConnection)

# Sinon lancement de la boucle de connexion FAI
else
  repeat

    # Connexion au 1er FAI de la liste (Fai.ini) qui répond
    cxmulti

    # Indication du nom du provider en cas de connexion
    if( RasIsConnected )
      print("Connecté à "+RasGetConnection)

    # Retour en début de boucle dans le cas contraire
    else
      Warning("Le script OZPlan n'a pas pu se connecter, _
               reconnection dans 25 minutes.")
      sleep(1500000)
    endif
  until(RasIsConnected)
endif

# Connexion au(x) serveur(s) de news.
HamNewsJobsStart

# Envoi du courrier en instance.
EnvoieCourrier

# Réception du courrier.
RecoitCourrier

# Déconnexion du FAI si c'est OZPlan qui s'est connecté
if($CxHamster)
  HamWaitIdle
  HamRasHangup
endif

HamWaitIdle

print("Traitement du courrier et des news effectué.")

endsub